SpriteFlashColour - Learn To Code - PlayBASIC Documentation

SpriteFlashColour

SpriteFlashColour SpriteIndex, FlashColour

Parameters:

SpriteIndex = The identifier of the sprite you wish to change
FlashColour = The RGB colour

Returns: NONE

SpriteFlashColour sets the sprites flash colour when it's drawmode is set to colour flash. When this draw mode is enabled, all the none transparent pixels in the image are replaced with the flash colour.

FACTS:

* SpriteFlashColour is only used when the sprites drawmode is set to colour flash.

* See SpriteDrawMode for more information about draw modes.

Example Source: Download This Example

; Load Bubble Media which is located two folders back from
; this path.

  BubbleImage=LoadNewImage("..\../Media/bubble_64x64.bmp")
  PrepareFXImage BUbbleImage


; Create a number of ranomdly positioned sprites
  For lp=1 To 25

   ; Get a random coord on the screen
     X=Rnd(GetScreenWidth())
     Y=Rnd(GetScreenHeight())

   ; Create a sprite
     Spr=NewSprite(X,y,BubbleImage)

   ; Center this sprites handle
     CenterSpriteHandle Spr

   ; Set this sprites drawmode to plain rotated
     SpriteDrawMode Spr, 2

   ; Set the sprites colour flash colour
     SpriteFlashColour   spr,RndRGB()

  Next


; limit the program to a max of 75 frames per second
  SetFPS 75



  Do
   ; Clear the Screen
     Cls RGB(30,40,70)


   ; Get the Mouse Pointers Position
     mX=MouseX()
     mY=MouseY()


   ; Update the Sprites
     TurnSpeed#=1

     Sprite=GetFirstSprite()
     While Sprite



      ; check if the mouse pointer is hitting this sprite
        If PointHitSpritePixels(mx,my,sprite,1)=false

         ; Turn This sprite
           TurnSprite Sprite,TurnSpeed#

         ; Set this sprites drawmode to rotated
           SpriteDrawMode Sprite, 2

        Else

         ; Set this sprites drawmode to rotated
         ; with pixel FADE
           SpriteDrawMode Sprite, 2+1024


        EndIf


      ; Bump The Turn Speed
        TurnSpeed#=TurnSpeed#+0.25



      ; Get the NExt Sprite
        Sprite=GetNextSprite(Sprite)
     EndWhile


   ; Draw All The Sprites
     DrawAllSprites


   ; Display information
     Print "Move The Mouse Over Sprites"

   ; Show the screen
     Sync

   ; Loop back to the Do statement to keep program running
  Loop


Related Info:	SpriteDrawMode :